# "md5check" version 1 (3/17/94)
BEGIN { FS = "[ \t]*:[ \t]*"; }

# Print notices from the configuration file
/^##/ { print substr ($0, 3); next; }

# Only handle MD5 checksums currently
/^md5/ {
        source = sprintf("%-7s %-8s %-6s %s", $2, $3, $5, $4);
        file = $6;
        sum = hex_lower($7);
        if (md5[file] == "") {
                print "Checking", file;
                testcmd = "test -r " file;
                if ( system(testcmd) != 0 ) {
                        print " Could not open", file;
                        md5[file] = "x";
                        next;
                } else {
                        md5cmd = "md5 " file
                        md5cmd | getline md5[file];
                        close (md5cmd);

                        # Strip off any leading text and set to lowercase
                        sub(".*[ \t]", "", md5[file]);
                        md5[file] = hex_lower(md5[file]);
                }
        }
        if (md5[file] == "x" || file in matched) {
                # Could not open or already matched
                next;
        }
        if (md5[file] == sum) {
                # We have a match - remember which one
                matched[file] = source;
                num_match++;
                if (file in not_matched) {
                        num_no_match--;
                        delete not_matched[file];
                }
        } else {
                if (! (file in not_matched)) {
                        num_no_match++;
                        not_matched[file] = 1;
                }
        }
}

END {
        printf "\n%d files DID NOT MATCH a known checksum\n", num_no_match;
        printf "%d files did match a known checksum\n", num_match;

        print "\nThe following files DID NOT MATCH a known checksum";
        for (filename in not_matched) {
                printf "\t%s\n", filename;
        }

        print "\nThe following files did match a known checksum";
        for (filename in matched) {
                printf "\t%s\n\t\t%s\n", filename, matched[filename];
        }

}
function hex_lower(s) {
     gsub("A","a",s); gsub("B","b",s); gsub("C","c",s);
     gsub("D","d",s); gsub("E","e",s); gsub("F","f",s);
     return s
}